Function runScript(_self, _cScriptName)
// ---------------------------
// Änderung der Maklervereinbarung
// ---------------------------
// benötigte Script's
global AusgabeAgtNr := _cScriptName + "01.txt"
global AusgabeFussZeile := _cScriptName + "02.txt"
global AusgabeGeschZeit := _cScriptName + "03.txt"
global AusgabeHinweis  := _cScriptName + "04.txt"
global AusgabeKopfZeile := _cScriptName + "05.txt"
global AusgabeTelFax := _cScriptName + "06.txt"
global AusgabeText := _cScriptName + "07.txt"
global DrawGreyBox := _cScriptName + "08.txt"
global DrawGreyTabLine := _cScriptName + "09.txt"
global DrawHalfBox := _cScriptName + "10.txt"
global Umbruch := _cScriptName + "11.txt"


local m,n,i,x
local cText
local cEmail
local cKdAlt
local nTab1, nTab2 ,nTab3

local aAnschreiben
local aKdAngaben

aAnschreiben := _self:aAnschreiben
aKdAngaben := _self:aKdAngaben

// Ausgabe
IF ( n := Len( aAnschreiben )) > 0

  FOR m := 1 TO n

    // Beginn Seite erzeugen				
    _SELF:seite_neue_seite()
    _SELF:seite_waehle_papierformat( _self:_papier_A4(), _self:_format_hochformat() )
    _SELF:seite_setze_raender( _self:nRandLinks, _self:nRandOben, _self:nRandRechts, _self:nRandUnten )
    _SELF:wYTemp := 0
    _SELF:AusgabeBmp()
    ExecuteScript(AusgabeFussZeile, _self)	
    ExecuteScript(AusgabeKopfZeile, _self)
    ExecuteScript(AusgabeTelFax, _self)
    ExecuteScript(AusgabeGeschZeit, _self)
    ExecuteScript(AusgabeAgtNr, _self, aAnschreiben[m][6])
    _SELF:waehle_stift( _self:_stift_durchgezogen(), 1 )
    _Self:waehle_farbe( _self:_farbe_schwarz() )
    _SELF:waehle_schrift( "ARIAL", 40, _self:_schrift_roman(), _self:_attr_normal() )

// ------------------------------------------------------------
// Tabs ( erst jetzt, da erst jetzt SELF:seite_x_ausdehnung() bekannt ist )
// ------------------------------------------------------------
    nTab1 := 0
    nTab2 := 500
    nTab3 := _SELF:seite_x_ausdehnung()

// ------------------------------------------------------------
// Anschrift
// ------------------------------------------------------------
// { {vu_name,vu_str,vu_plz,vu_ort,{police_vsnr,police_produkt},#VU,AgtNr},{...}},   ... }
    _SELF:wYTemp := _SELF:nY_Pos_Anschr_Text
    // VU-name
    IF ! Empty(aAnschreiben[m][1])	
      _SELF:txt_gerichtet( _SELF:wYTemp, _self:_txt_links(), AllTrim(aAnschreiben[m][1]))
      _self:wYTemp := _self:wYTemp + 50
    ENDIF			
    // vu_straße
    IF ! Empty(aAnschreiben[m][2])	
      _SELF:txt_gerichtet( _SELF:wYTemp, _self:_txt_links(), AllTrim(aAnschreiben[m][2]))
      _self:wYTemp := _self:wYTemp + 80
    ENDIF
    IF ! Empty(aAnschreiben[m][3]+aAnschreiben[m][4])	// vu_plz+ort
      _SELF:txt_gerichtet(_SELF:wYTemp, _self:_txt_links(),AllTrim(aAnschreiben[m][3])+" "+AllTrim(aAnschreiben[m][4]))
      _self:wYTemp := _self:wYTemp + 50
    ENDIF

// ------------------------------------------------------------
// Ihr Ansprechpartner
// ------------------------------------------------------------
    _self:wYTemp := _self:wYTemp + 130
    _SELF:waehle_stift( _self:_stift_durchgezogen(), 1 )
    _SELF:waehle_farbe( _self:_farbe_schwarz() )
    _SELF:waehle_schrift( "ARIAL", 20, _self:_schrift_roman(), _self:_attr_normal() )
    _SELF:txt_absolut(0,_SELF:wYTemp,"Ihr Ansprechpartner")
    _SELF:txt_gerichtet(_SELF:wYTemp,_self:_txt_rechts(),"Datum")
    _self:wYTemp := _self:wYTemp + 30
    _SELF:waehle_schrift( "ARIAL", 40, _self:_schrift_roman(), _self:_attr_normal() )
    _SELF:txt_gerichtet(_SELF:wYTemp, _self:_txt_rechts(),DToC(Today()))
    _SELF:waehle_schrift( "ARIAL", 30, _self:_schrift_roman(), _self:_attr_normal() )
    _SELF:txt_absolut(0,_SELF:wYTemp, _self:pdf_cUserNameFromUserNr(_self:pdf_nUserNr()))
    _SELF:txt_absolut(0,_SELF:wYTemp+30,"Durchwahl "+_self:pdf_cUserDurchwahlFromUserNr(_self:pdf_nUserNr()))
    IF ! Empty(cEmail := _self:pdf_cUserEmailFromUserNr(_self:pdf_nUserNr()))
      _self:wYTemp := _self:wYTemp + 30
      _SELF:txt_absolut(0,_SELF:wYTemp+30,"email "+cEmail)
    ENDIF
    _self:wYTemp := _self:wYTemp + 130

// ------------------------------------------------------------
// Makleranzeige - Bestandsübertragung
// ------------------------------------------------------------
    _SELF:waehle_schrift( "ARIAL", 40, _self:_schrift_roman(), _self:_attr_normal() )
    IF ! Empty(aAnschreiben[m][6])	// AgtNr
      _SELF:txt_absolut(0,_SELF:wYTemp,"Makleranzeige - Bestandsübertragung")
    ELSE
      _SELF:txt_absolut(0,_SELF:wYTemp,"Makleranzeige")
    ENDIF
    _self:wYTemp := _self:wYTemp + 50
// ------------------------------------------------------------
// Linie
// ------------------------------------------------------------
    _SELF:waehle_farb_pinsel()
    _SELF:waehle_farbe( _self:_farbe_schwarz() )
    _SELF:waehle_stift( _self:_stift_durchgezogen(), 3 )
    _SELF:gdi_line( 0, _SELF:wYTemp, _SELF:seite_x_ausdehnung(), _SELF:wYTemp )
    _self:wYTemp := _self:wYTemp + 80

// ------------------------------------------------------------
// Kunde
// ------------------------------------------------------------
    _SELF:txt_absolut(0,_SELF:wYTemp,"Kunde:")
    // name
    cKdAlt := ""
    IF ! Empty(aKdAngaben[5])		// titel
      cKdAlt := cKdAlt + AllTrim(aKdAngaben[5])+" "
    ENDIF
    IF ! Empty(aKdAngaben[4])		// vorname
      cKdAlt := cKdAlt + AllTrim(aKdAngaben[4])+" "
    ENDIF
    IF ! Empty(aKdAngaben[2])		// name
      cKdAlt := cKdAlt + AllTrim(aKdAngaben[2])+" "
    ENDIF
    _SELF:txt_absolut(400,_SELF:wYTemp,cKdAlt)
    // zusatz
    IF ! Empty(aKdAngaben[3])
      _self:wYTemp := _self:wYTemp + 50
      _SELF:txt_absolut(400,_SELF:wYTemp,AllTrim(aKdAngaben[3]))
    ENDIF

// ------------------------------------------------------------
// Sehr geehrte Damen ...
// ------------------------------------------------------------
    _self:wYTemp := _self:wYTemp + 80
    _SELF:waehle_schrift( "ARIAL", 40, _self:_schrift_roman(), _self:_attr_normal() )
    _SELF:txt_absolut(0,_SELF:wYTemp,"Sehr geehrte Damen und Herren,")
    _self:wYTemp := _self:wYTemp + 100
    IF ! Empty(aAnschreiben[m][6])	// AgtNr
      cText := "unter Vorlage der Maklervereinbarung zeigen wir an, den o.g. Kunden zu vertreten. Wir bitten Sie" + ;
                 	" den/die u.g. Vertrag/Verträge in unsere Verwaltung (Agentur "+aAnschreiben[m][6]+") zu übertragen und den" + ;
									" gesamten Geschäftsverkehr künftig über uns zu führen."
      ExecuteScript(AusgabeHinweis, _self, cText)
      _self:wYTemp := _self:wYTemp + 100
    ELSE
      cText := 	"unter Vorlage der Maklervereinbarung zeigen wir an, den o.g. Kunden zu vertreten. Wir bitten Sie" + ;
							" den gesamten Geschäftsverkehr künftig über uns zu führen."
      ExecuteScript(AusgabeHinweis, _self, cText)
      _self:wYTemp := _self:wYTemp + 50
    ENDIF

// ------------------------------------------------------------
// Policennummern
// ------------------------------------------------------------
    _self:wYTemp := _self:wYTemp + 80
    ExecuteScript(DrawGreyBox, _self)
    _self:wYTemp := _self:wYTemp + 60
    IF ( i := Len(aAnschreiben[m][5])) > 0	// {vsnr,produkt}
      FOR x := 1 TO i
        ExecuteScript(DrawGreyTabLine, _self, nTab1)
        ExecuteScript(DrawGreyTabLine, _self, nTab2)
        ExecuteScript(DrawGreyTabLine, _self, nTab3)
        _SELF:waehle_schrift( "ARIAL", 40, _self:_schrift_roman(), _self:_attr_normal() )
        _SELF:txt_bereich(nTab1+10,_SELF:wYTemp,nTab2-10,_SELF:wYTemp+40,_self:_txt_links(),AllTrim(aAnschreiben[m][5][x][1]))	    // vsnr
        _SELF:txt_bereich(nTab2+10,_SELF:wYTemp,nTab3-10,_SELF:wYTemp+40,_self:_txt_links(),AllTrim(_self:pdf_Art2Text2(aAnschreiben[m][5][x][2])))	    // produkt
        _self:wYTemp := _self:wYTemp + 50
        // Umbruch ?
        IF _SELF:wYTemp + 100 > _SELF:seite_y_ausdehnung() - _SELF:nFussZeilenHoehe
          ExecuteScript(Umbruch, _self, .T.)
        ENDIF
      NEXT x
      ExecuteScript(DrawHalfBox, _self)
    ENDIF

// ------------------------------------------------------------
// restlicher Umbruch
// ------------------------------------------------------------
    // Umbruch ?
    IF _SELF:wYTemp + 200 > _SELF:seite_y_ausdehnung() - _SELF:nFussZeilenHoehe
      ExecuteScript(Umbruch, _self, .F.)
    ENDIF
    _SELF:waehle_schrift( "ARIAL", 40, _self:_schrift_roman(), _self:_attr_normal() )
    _self:wYTemp := _self:wYTemp + 100
    cText := 	"Gleichzeitig bitten wir höflich um den aktuellen Policenstand. Nach Überprüfung kommen wir" + ;
		" unaufgefordert auf Sie zu. Sollten Sie noch Fragen haben stehen wir Ihnen gerne zur Verfügung."
    ExecuteScript(AusgabeHinweis, _self, cText)
    _self:wYTemp := _self:wYTemp + 50

// ------------------------------------------------------------
// Mit freundlichen ...
// ------------------------------------------------------------
    // Umbruch ?
    _self:wYTemp := _self:wYTemp + 150
    IF _SELF:wYTemp + 200 > _SELF:seite_y_ausdehnung() - _SELF:nFussZeilenHoehe
      ExecuteScript(Umbruch, _self, .F.)
    ENDIF

    _SELF:waehle_stift( _self:_stift_durchgezogen(), 1 )
    _SELF:waehle_farbe( _self:_farbe_schwarz() )
    _SELF:waehle_schrift( "ARIAL", 40, _self:_schrift_roman(), _self:_attr_normal() )
 
    ExecuteScript(AusgabeText, _self, _SELF:wYTemp,_self:_TXT_LINKS(),_SELF:cTxt_mfG,40)

  NEXT m

ENDIF

RETURN
